On 3 Aug 2004, at 22:05, Edwards, Waverly wrote:

> I would like to programmatically set the clock and date control.
> I can find out how to extract date and time information from the
> control but can not find a way to change it.
> I don't mean the date and time of the machine but a date or time
> control you add to your window.
> Anyone?

Try this, Wave:

'----------
'~'A
'                       Runtime : Rntm Appearance.Incl
'                           CPU : Carbon
'                    CALL Req'd : Off
'~'B

_SetClockControlDemoWnd = 1
begin enum 1
_cClockHMS
_cClockMDY
_cClockHM
_cClockMY
end enum

local fn BuildSetClockControlDemoWnd
dim as Rect r
'~'1
SetRect(r, 241, 190, 685, 445)
appearance window -_SetClockControlDemoWnd,¬
                   "Set Clock Control Demo", @r,¬
                   _kDocumentWindowClass
def SetWindowBackground(_kThemeActiveDialogBackgroundBrush, _zTrue)
'~'1
SetRect(r, 178, 53, 264, 73)
appearance button _cClockHMS,¬
                   _activeBtn, _kControlClockNoFlags,,,, @r,¬
                   _kControlClockTimeSecondsProc

SetRect(r, 178, 81, 285, 101)
appearance button _cClockMDY,¬
                   _activeBtn, _kControlClockNoFlags,,,, @r,¬
                   _kControlClockDateProc

SetRect(r, 178, 109, 285, 129)
appearance button _cClockHM,¬
                   _activeBtn, _kControlClockIsDisplayOnly,,,, @r,¬
                   _kControlClockTimeProc

SetRect(r, 178, 137, 285, 157)
appearance button _cClockMY,¬
                   _activeBtn, _kControlClockIsDisplayOnly,,,, @r,¬
                   _kControlClockMonthYearProc

appearance window _SetClockControlDemoWnd
end fn

local fn SetClockControls
dim as LongDateRec longDate
'~'1
longDate.hour = 2
longDate.minute = 33
longDate.second = 12
def SetButtonData(_cClockHMS, _kControlEditTextPart, 
_kControlClockLongDateTag, SizeOf(LongDateRec), @longDate)

longDate.year = 2010
longDate.month = 9
longDate.day = 30
def SetButtonData(_cClockMDY, _kControlEditTextPart, 
_kControlClockLongDateTag, SizeOf(LongDateRec), @longDate)

longDate.hour = 14
longDate.minute = 2
def SetButtonData(_cClockHM, _kControlEditTextPart, 
_kControlClockLongDateTag, SizeOf(LongDateRec), @longDate)

longDate.year = 2002
longDate.month = 3
def SetButtonData(_cClockMY, _kControlEditTextPart, 
_kControlClockLongDateTag, SizeOf(LongDateRec), @longDate)
end fn

fn BuildSetClockControlDemoWnd
fn SetClockControls

do
HandleEvents
until gFBQuit